Premiers pas

Tracer des courbes

(*Tracer des fonctions*)
Plot[Sin[x],{x,0,6Pi}]
Plot[{Sin[x],Sin[2x],Sin[3x]},{x,0,2Pi},PlotLegends->"Expressions"]
Plot[{Sin[x],Sin[2x],Sin[3x]},{x,0,2Pi},PlotStyle->{Red,Green,Blue},PlotLegends->"Expressions",AxesLabel->{"x","toto"}]

(*Tracer des listes*)
a=Table[{x,Sin[x]},{x,0,2 Pi,0.1}]
ListPlot[a]
ListLinePlot[a]

b=Table[{x,Sin[2x]},{x,0,2 Pi,0.1}];
c=Table[{x,Sin[3x]},{x,0,2 Pi,0.1}];
ListLinePlot[{a,b,c}]

(*Supperposer des graphes*)
desa=ListLinePlot[a,PlotStyle->Red];
desb=Plot[Sin[2x],{x,0,2Pi},PlotStyle->Blue,PlotLegends->"Expressions",AxesLabel->{"x","toto"}];
Show[{desa,desb}]

Définitions

(*Il existe une différence entre = et := *)
ClearAll[a,b,c];
a=1;
b=a;
c:=a;
Print["a = ",a,", b = ",b,", c= ",c]

a=2
Print["a = ",a,", b = ",b,", c= ",c]

?b
?c

(*définition d'une fonction - remarquez les couleurs automatiquement utilisées par Mathématica*)
f[x_,y_]:=Sin[x]/(2+Sin[y]);
f[a,b]
f[d,e]
f[3,2]
N[f[3,2]]

(*remarquez les couleurs automatiquement utilisées par Mathématica*)
Plot[f[a,b],{a,1,10}]
Plot3D[f[a,b],{a,1,10},{b,1,10}]
ContourPlot[f[a,b],{a,1,10},{b,1,10}]

Résolutions

ClearAll[f,g,h];
f[x_]:=Sin[x];
g[x_]:=x+(x^2)-2;
h[x_]:=((3x+3)/(2x+8));
Plot[{f[x],g[x],h[x]},{x,-10,10}]

(*résolution exacte*)
Solve[f[x]==0,x]
Solve[g[x]==0,x]
Solve[h[x]==0,x]

Solve[g[x]==h[x],x]
N[%]

Solve[f[x]==g[x],x]

(*résolution numérique*)
NSolve[f[x]==g[x],x]

(*recherche d'une solution autour d'une valeur*)
FindRoot[Sin[x]-(-2+x+(x^2)),{x,1}]

Manipulation des listes

ClearAll[a,b,c,d];
a=Table[RandomReal[NormalDistribution[0,1]],1000];
Histogram[a]
CDF[NormalDistribution[0,1],3]//N

(*Quelques manipulations*)
Take[a,10]
a[[1]]
Last[a]

(*Quelles sont les statistiques de la liste a?*)
Max[a]
Min[a]
Mean[a]
StandardDeviation[a]

a:=Table[RandomReal[NormalDistribution[0,1]],{1000}]
Mean[a]
StandardDeviation[a]

(*Quelle est la proportion des valeurs supèrieures à 2 dans la liste a ?*)
b=2
c=Select[a,#>b&]
Length[c]/Length[a]//N
1-CDF[NormalDistribution[0,1],b]//N

(*Je veux comparer 10 calculs où je calcule la moyenne de la liste a et je calcule l'écart entre les deux valeurs extrêmes de la list a*)
d=Table[a,10];
Map[Mean,d]
Map[Max[#]-Min[#]&,d]

A vous de jouer

https://fr.wikipedia.org/wiki/Trajectoire_d%27un_projectile
Créer la fonction permettant de calculer la distance horizontale totale d parcourue jusqu’à ce que le projectile retombe au sol (vitesse initiale v, angle initial α, hauteur du lancé h)

Tracer d en fonction de α pour une vitesse initiale de 50 km/h et une hauteur initiale nulle

Un lanceur de hauteur essaye  d’adopter un angle de 45° et lance avec une vitesse initiale d’environ 50 km/h et une hauteur initiale de 1,5m. On considèrera une incertitude de 20% sur l’angle et 15% sur la vitesse (coefficient de variation). Tracer l’histogramme de la distance d pour 1000 lancers.

Calculez les statistiques du résultat : moyenne, écart type.

Ajustez un modèle statistique sur ce résultat.

ClearAll[d];
g=9.81;
d[α_,v_,h_]:=(v/g) Cos[α]*(v Sin[α]+(Sqrt[(((v Sin[α]))^2)+2 g h]));
Plot[d[a,50/3.6,0],{a,0,Pi/2}]
Plot[d[a,50/3.6,0],{a,0,90 Degree}]

list=Table[d[RandomReal[NormalDistribution[Pi/4,0.2 Pi/4]],RandomReal[NormalDistribution[50/3.6,0.15 50/3.6]],1.5],1000];
des1=Histogram[list,Automatic,"PDF"]
Mean[list]
StandardDeviation[list]
des2=Plot[PDF[NormalDistribution[Mean[list],StandardDeviation[list]],x],{x,0,30}]
Show[des1,des2]